MENAMPILKAN TANGGAL DAN JAM AKTIF DI USERFORM EXCEL

Pada kesempatan kali ini kita akan belajar membuat atau menampilkan tanggal dan jam aktif di UserForm Excel, yang di maksud tanggal adalah tanggal hari ini sesuai dengan tanggal komputer dan jam aktif sesuai dengan jam pada komputer yang digunakan. Dan seperti biasanya di akhir postingan akan kami sediakan File contoh latihan-nya yang bisa di download gratis.

Untuk menampilkan tanggal dan Jam pada UserForm Excel sebenarnya ada banyak cara, namun pada kesempatan kali ini kami akan membagikan 3 cara atau 3 versi saja.

Menampilkan Tanggal dan Jam versi I

Untuk versi yang pertama menampilkan tanggal dan jam aktif di UserForm Excel caranya adalah sebagai berikut:

1. Buka aplikasi Microsoft Visual Basic for Applications bisa melalui tab Developer atau bisa juga dengan menekan tombol Alt+F11.
2. Tambahkan sebuah UserForm dan sebuah Label. Kemudian pada tempat kode UserForm1 masukkan script VBA berikut ini:

Option Explicit
Private m_lasttime As Date
Private Sub UserForm_Initialize()
Label1 = Format(Now, "dd mmmm yyyy   hh:mm:ss")
m_lasttime = Now + TimeValue("00:00:01")
Application.OnTime m_lasttime, "GetTime"
End Sub
Public Property Get LastTime() As Date
LastTime = m_lasttime
End Property
Public Property Let LastTime(ByVal Value As Date)
m_lasttime = Value
End Property
Private Sub userform_QueryClose(Cancel As Integer, CloseMode As Integer)
Application.OnTime m_lasttime, "GetTime", , False
End Sub

3. Tambahkan lagi sebuah Module dan masukkan script VBA berikut ini:

Option Explicit
 
Public Sub GetTime()
 
Dim ld As Date
 
UserForm1.Label1 = Format(Now, "dd mmmm yyyy   hh:mm:ss")
ld = Now + TimeValue("00:00:01")
 
UserForm1.LastTime = ld
Application.OnTime ld, "GetTime"
 
End Sub

4. Kembali ke UserForm1 dan tekan tombol F5 untuk menjalankan UserForm dan UserForm akan menampilkan tanggal dan jam aktif sesuai komputer yang digunakan.
   

Menampilkan Tanggal dan Jam versi II

Untuk versi yang kedua tutorial menampilkan tanggal dan jam aktif di UserForm Excel caranya adalah sebagai berikut:

1. Buka aplikasi Microsoft Visual Basic for Applications bisa melalui tab Developer atau bisa juga dengan menekan tombol Alt+F11.
2. Tambahkan sebuah UserForm dan 2 buah Label, 1 label untuk menampilkan tanggal dan satu lagi untuk menampilkan jam aktif. Kemudian pada tempat kode UserForm1 masukkan script VBA berikut ini:

Private Sub UserForm_Activate()
Call JamAktif
End Sub

Private Sub userform_QueryClose(Cancel As Integer, CloseMode As Integer)
On Error Resume Next
    Application.OnTime TimeABC, "JamAktif", , False
End Sub

3. Tambahkan lagi sebuah Module dan masukkan script VBA berikut ini:

Option Explicit
Public TimeABC As Single
Sub JamAktif()
    UserForm1.Label1 = Format(Date, "dd mmmm yyyy")
    UserForm1.Label2.Caption = Time() + TimeValue("00:00:01")
    TimeABC = Time() + TimeValue("00:00:01")
    Application.OnTime TimeABC, "JamAktif", TimeABC + TimeValue("00:00:01")
End Sub

4. Kembali ke UserForm1 dan tekan tombol F5 untuk menjalankan UserForm dan UserForm akan menampilkan tanggal dan jam aktif sesuai komputer yang digunakan.
   

Menampilkan Tanggal dan Jam versi III

Untuk versi yang ketiga dalam tutorial cara menampilkan tanggal dan jam aktif di UserForm Excel, caranya hampir sama dengan yang versi kedua yaitu:

1. Buka aplikasi Microsoft Visual Basic for Applications bisa melalui tab Developer atau bisa juga dengan menekan tombol Alt+F11.
2. Tambahkan sebuah UserForm dan 2 buah Label, 1 label untuk menampilkan tanggal dan satu lagi untuk menampilkan jam aktif. Kemudian pada tempat kode UserForm1 masukkan script VBA berikut ini:

Private Sub UserForm_Activate()
Application.Run "StartTimer"
End Sub

Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
StopTimer
End Sub

3. Tambahkan lagi sebuah Module dan masukkan script VBA berikut ini:

Option Explicit
Dim TM

Sub StopTimer()
On Error Resume Next
Application.OnTime TM, Procedure:="Update", Schedule:=False
End Sub

Sub StartTimer()
TM = Now + TimeValue("00:00:01")
Application.OnTime TM, "Update"
End Sub

Sub Update()
UserForm1.Label1 = Format(Date, "dd mmmm yyyy")
UserForm1.Label2 = Format(Now, "hh:mm:ss")
Call StartTimer
End Sub

4. Kembali ke UserForm1 dan tekan tombol F5 untuk menjalankan UserForm dan UserForm akan menampilkan tanggal dan jam aktif sesuai komputer yang digunakan.
   

Tweet